Hi everyone!
I’m wondering how to produce something similar to the stuttering sound in very high frequencies, from 25’25" to 26’30" in this beautiful piece by Kassel Jaeger (aka François Bonnet):
https://kasseljaeger.bandcamp.com/album/meith
I thought of static noise filtered with just the high frequencies, but the result is very different…
Any idea?
2 Likes
vmx
December 2, 2021, 12:58pm
2
Hi,
Maybe this is a starting point?
SynthDef(\pling, {
var freq = \freq.kr();
var sig = (SinOsc.ar(freq) * SinOsc.ar(Rand(10,30)) * 0.2) + SinOsc.ar(freq * {Rand(2.91,3.02)}!2);
var env = EnvGen.ar(Env.perc(\att.kr(0.01), \rel.kr(0.3)), doneAction: 2);
sig = sig * env * \amp.kr(0.1);
Out.ar(0, sig ! 2)
}).add;
Pbind(
\instrument, \pling,
\dur, Pwhite(0.003,0.05),
\freq, Pwhite(3785,3800),
\amp, Pwhite(0.01,0.1),
\att, Pwhite(0.001,0.01),
\rel, Pwhite(0.02, 0.1)
).play
1 Like
shiihs
December 2, 2021, 8:25pm
3
Here’s another attempt:
(
s.waitForBoot({
SynthDef(\plong, {
| out=0, amp=0.1, freq=2700 |
var sig1 = HPF.ar(amp * Convolution.ar(Saw.ar(freq), Dust.ar(100)), 10000);
var sig2 = HPF.ar(amp * Convolution.ar(Saw.ar(freq), Dust.ar(100)), 10000);
Out.ar(out, [sig1, sig2])
}).add;
s.sync;
Synth(\plong);
});
)
1 Like
Thank you guys, you are awesome! Very good starting points! The one suggested by @shiihs sounds very close to the original.
Not perfect, but a nice sound:
(
{
var trig = Dust.kr(25);
var sound = DynKlank.ar(`[(1..5)*2700, TRand.kr(0.025,0.04,trig!5), 0.1!5], Trig.ar(trig, 1/SampleRate.ir), 1, 0, 1);
sound = sound + (BrownNoise.ar(0.075)*Trig.kr(trig, TRand.kr(0.01,0.03,trig).poll));
sound = LPF.ar(HPF.ar(sound, TRand.kr(6000, 7500, trig).lag(0.01)), TRand.kr(4000, 5500, trig).lag(0.01));
Pan2.ar(sound, TRand.kr(-0.5, 0.5, trig).lag(0.01))
}.play
)
1 Like
Thank you @Sam_Pluta for introducing me the object DynKlank
, very interesting!