Thatās not quite what I meantā¦ but thatās alright, I donāt mean to argue, just to point out that what music means to you (and what you are trying to achieve with SC) might not be universal. (For example, someone might be into parsing legal documents using occurrences of the letter āFā to determine musical timing, modulating the data stream with sensors measuring the electrical activity in a houseplant, using this to control a hardware synthesizer via MIDI, and then granularly processing the resulting sound before streaming it to a website. This is all reasonably straightforward to do using SC.)
Would you like to elaborate on the structures youāre imagining and how they might differ from the patterns that already exist? It sounds to me like youāve described a lot of the functionality of patterns, for example:
( // Timbres
SynthDef(\bandura, { |out, freq = 500, gate = 1, amp = 1, pan, decay = 1, rt = 10|
var sig;
sig = SelectX.ar(amp.explin(0.25, 1, 0, 1), [PinkNoise.ar(0.5), WhiteNoise.ar(0.5)]);
sig = Pluck.ar(sig, 1, 0.2, freq.reciprocal, (freq * decay), 0.5);
sig = sig + (SinOsc.ar(freq / 2) * Env.adsr(0.01, 10, 0.1, rt).kr(0, gate, mul: 0.005));
sig = sig * amp;
sig = LeakDC.ar(sig) * 2;
DetectSilence.ar(sig, doneAction: 2);
sig = Pan2.ar(sig, pan);
Out.ar(out, sig);
}).add;
SynthDef(\chaoticwhistle, { |out, pan, amp = 1, freq = 3000, foldlo = 0, gate = 1, at = 5, rt = 10|
var in = LocalIn.ar(1);
var inslow = Latch.ar(in, Impulse.ar(in.exprange(1, 10))).lag(in.range(0, 0.1));
var sig = SinOsc.ar((in.exprange(20, freq)));
var sig2 = Fold.ar(sig, foldlo * in, inslow.range(0.5, 1));
LocalOut.ar(sig2);
sig = sig * amp * Env.adsr(at, 0, 1, rt).kr(2, gate);
sig = Pan2.ar(sig, pan);
Out.ar(out, sig);
}).add;
)
(
p = Ppar([
Pbind(
\instrument, \chaoticwhistle, // Timbre
\midinote, Pwhite(30, 80), // Note
\dur, Pwhite(5, 15) // Timing
),
Pn(
Pbind(
\instrument, \bandura, // Timbre
\scale, Scale.harmonicMinor, // Note
\degree, Pbrown(-12, 12, 3), // Note
\dur, Pgeom(1, 0.9, 100) // Timing
),
inf
)
]).play;
)
p.stop;
Maybe you could demonstrate what a structure like this might look like in your ideal environment?