Tracking Ndef activity

Questions
1

I would like to track some information from various Ndefs which run simultaneously on the server.

For example, how long a Ndef is being active. NodeWatcher could do that but the Ndef uses dynamic nodeIDs. Is it possible to create Ndefs with static nodeIDs in order to register them in the NodeWatcher?

Additionally, I would like to track the RunningSum from each Ndef. Would this be possible at all?

2

There are this.changed calls for: the following methods:

NodeProxy.methods.select { |x| x.selectors.asArray.includes(\changed) }.collect { |x| x.name }
[ clear, end, free, pause, resume, put, removeAt, rebuildToBundle ]

So you can work with a SimpleController to catch these.

They call, respectively:

\clear -> \clear,
\end -> \end,
\freq -> \free,
\pause -> \pause,
\resume -> \resume,
\put -> \source, // source changed
\removeAt -> \source, // source changed
\rebuildToBundle -> \rebuild, // source rebuilt
1 Like
3

Thanks, that looks great!

Could you please provide a simple example with a Ndef? I cannot figure out how to apply these methods and the help files don’t help me much…

4 
(
~controllers = ();
~registerNdef = { |obj, what, func|
	var ctrl = ~controllers.at(obj);
	if(ctrl.isNil) { ctrl = SimpleController(obj); ~controllers[obj] = ctrl };
	ctrl.put(what, func)
};
~unregisterNdef = { |obj, what, func|
	var ctrl = ~controllers.at(obj);
	if(ctrl.notNil) { ctrl.remove; ~controllers.removeAt(obj) }
};
)




~registerNdef.(Ndef(\x), \source, { "source has changed!".postln });

Ndef(\x, { SinOsc.ar * 0.1 });

~unregisterNdef.(Ndef(\x));

For more, you need to read up on SimpleController

5

Thanks so much!

I am trying to track the duration of a Ndef being active:

(
var temp=0;

~registerNdef.(Ndef(\x), \source, {
	var dur, abs_time = Main.elapsedTime;
	if (Ndef(\x).source.isFunction)
	{temp = abs_time}
	{dur = abs_time - temp; dur.postln;};
});
)

Ndef(\x, { SinOsc.ar * 0.01 }).play;
Ndef(\x, { SinOsc.ar * 0.01 }).clear;

When the clear method is called the controller is activated twice. In the first activation, the source is still a function, thus reassigning the temp variable and messing up the duration calculation. Is there any workaround that?

6

I found another way to track the current rms of a Ndef:

(
~accumulated_amplitudes = Dictionary();

~trackRMS = {
	arg tag;
	var bus = Bus.control(s);

	//write the accumulated rms in a private control bus
	{RunningSum.kr(Mix.ar(Ndef(tag).ar).squared).sqrt}.play(outbus: bus);

	//insert the bus to the dictionary
	~accumulated_amplitudes.put(tag, bus)
}
)

Just creating private buses for each Ndef, writing the RMS and storing the pair in a dictionary.

7

Try this:

~registerNdef.(Ndef(\x), \source, { |...args| args.postln });
Ndef(\x, { SinOsc.ar * 0.01 });
Ndef(\x).clear;

The arguments tell you what.

// from NodeProxy::put:
		this.changed(\source, [obj, index, channelOffset, extraArgs, now]);
8

I keep making the same mistake, I should call the clear method without setting a source for the Ndef.

Ndef(\x).clear;