Event pattern for both synthesis and MIDI output

[moscardo]

I would like to be able to have an event pattern that is capable of outputting note events and MIDI events simultaneously so that I can record both the sound result and the originating MIDI data on an external DAW.

To do this, after starting the server and instantiating a MidiOut:

s.boot;
MIDIClient.init;
MIDIIn.connectAll;
~midi_out = MIDIOut(0);

I tried the first thing that came to mind, which was to use the \type key and assign it a symbols list containing \note (for note events) and \midi (for midi events):

(
Pbindef(\test,
	\type, [\note, \midi],

    // MIDI stuff
	\midicmd, \noteOn,
	\midiout, ~midi_out,
    \chan, 0,

    // "sound synthesis" stuff
	\instrument, \default,
	\octave, 5,
	\degree, 0,
	\dur, 1,
	\amp, 1.0,
	\out, 0,
).quant_([4]).play;
);

But while this causes SC to output sound, as I expect, it does not produce any MIDI data output.

• why?
• How can I achieve the desired result?

---

In order to better understand the inner workings of SC, I ask a further question: why does it work and produce two independent sounds?

(
Pbindef(\test2,
	\instrument, \default,
	\octave, 5,
	\degree, [0,4],
	\dur, 1,
	\amp, 1.0,
	\out, 0,
).quant_([4]).play;
);

• Is it actually two note events, or is it rather a single note event?
• It occurs to me that when a list is passed as an argument, the event pattern behaves differently depending on whether the key is \type or something else (e.g. \degree).

[dkmayer]

Hi,

to the first part of the question see these old threads:

MIDI and audio out from Pbind?

I apologize as always if this question has been asked already. I searched and didn’t find anything. I’m trying to send MIDI data and audio out from a proxy node. Specifically the Pbind lives on the first slot of the proxy: ( ~lead = { | out = 0, freq = 48, relTime = 2 | var sig = 0, temp, env, curv; out.postln; // curv = [\step, \sin, \wel].scramble; env = EnvGen.kr(Env.perc(0.5, releaseTime:relTime, curve: \step), doneAction: 2); 8.do{ | i | temp = LFPulse.ar(freq + Rand(0, i), LFPulse…

Control hardware and server synth with one Pbind?

I’m trying to sync an external hardware synth and an internal synth using the same note events. Here’s a boiled down example of what I’m trying to do: MIDIClient.init; m = MIDIOut(1).latency = 0.01; ( SynthDef(\tone, {|out=0, gate=1, freq=440| var env = EnvGen.ar(Env.adsr(releaseTime:0.1 ), gate, doneAction:2); Out.ar(out, SinOsc.ar(freq!2, mul: env, mul:0.3)); }).add; ) a = Pbind(\degree, Prand([1, 2, 3], inf), \dur, Pwhite(1/4, 1, inf)); ( (a <> (instrument: \tone)).play; (a <> (type:…

One Pattern Playing Multiple Synths

Hi Everyone, My questions is simple enough but I’ve had a tough time finding a suitable solution. I’m working on a piece right now that uses synthDefs designed around organ stops. Like organ stops, I want to be able to play the same music with multiple stops, or synthDefs, engaged. In other words, I would like to have one pattern play multiple synths. The patterns in question generates a good amount of random data, which means if I Pchain the note/dur producing pattern to different instruments…

for the seconds part, see this recent one:

Patterns and Arrays

Hi all, finally got some time to do some colliding, but have been colliding my head against the wall in this particular case. Typing this up I’ve finally found a workaround but I’m still not sure why Patterns behave that way, so would be thankful for explanations. I am trying to get a \phrase-type Pdef to pass an array (of pitches) to a subordinate Pdef, and the subordinate pattern should then play these pitches sequentially (in a Pshuf or whatever). The superordinate pdef sends it new arrays …

[moscardo]

Thank you so much @dkmayer,
reading the refs you sent me, I was eventually able to get what I wanted the following way:

s.boot;
MIDIClient.init;
MIDIIn.connectAll;
~midi_out = MIDIOut(0);

(
Event.addEventType(\myEventType, { |server|
	currentEnvironment.copy.use {
		Event.eventTypes[\note].value(server);
	};
	Event.eventTypes[\midi].value(server);
});
);

(
Pbindef(\test,
	\type, \myEventType,
	\midicmd, \noteOn,
	\midiout, ~midi_out,
    \chan, 0,

	\instrument, \default,
	\octave, 5,
	\degree, Pseq((0..7),inf),
	\dur, 0.5,
	\amp, 1.0,
	\out, 0,

	\callback, Pfunc({ |e|
		e.postln;
		e.use{
			~type.postln;
		};
	})

).quant_([4]).play;
);

This way i both get the audio out from the server and the MIDI sent to my DAW.
I had to adjust the latency of the server a little in relation to that of the midiOut so as to synchronise the two outputs

~midi_out.latency_(0.1);
s.latency_(0.14);

but apart from that, it works great!

[dkmayer]

Glad to hear that it works for you !

@moscardo

I had to adjust the latency of the server a little in relation to that of the midiOut so as to synchronise the two outputs

Yes, that’s the “real world tweak” likely to be necessary. I remember that I had to experiment with latency as well the few times I had a similar setup.