Issue having nested pseqs

1

I’m having a headache creating nested pseq
I want some lists to transpose an repeat within a single Pseq
It works but as long as the parent Pseq also has some notes inside it , in the provided example the first notes (four times 72) are necessary to make the master Pseq repeat infinitly
Iow , I want to get rid of those .notes

(
SynthDef(\twoop,
{
|fmamt=2,modoffset=24,moatt=0.001,modrel=0.500,ampatt=0.001,amprel=0.800,pitch=48,outt=0.3,pan=0.2,feed=0.2|
var mod,modenv,ampenv,carr;

		mod=SinOscFB.ar((pitch+modoffset).midicps,feedback:feed)*fmamt;
		modenv=EnvGen.ar(Env.perc(moatt,modrel),doneAction:0);
		ampenv=EnvGen.ar(Env.perc(ampatt,amprel),doneAction:2);
		carr=SinOsc.ar(pitch.midicps,(mod*modenv))*ampenv*outt;
		carr=Pan2.ar(carr,pos:pan);
		Out.ar(0,carr);
}).add
);
//////////
(
Pdef(
	\crt,
	Pbind(
		\instrument,
		\twoop,
		\pitch,Pseq([72,72,72,72,Pseq([48,72,48,\,60,48,48,48]-10,4),Pseq([48,72,48,\,60,48,48,48]-17,2),Pseq([48,72,48,\,60,48,48,48]-15,2)],inf),
		\dur,Pseq([1/4,1/8,1/4,1/4,1/8,1/4,1/8,1/4],inf),
		\fmamt,Prand([2,1,3,4],inf),
		\modrel,Prand([0.425,0.525,0.500,0.550,1,0.625,0.500,0.5,2.8],inf),
		\modoffset,Prand([12,0,12,24],inf),
		\feed,Pwhite(0.3,0.5,inf),
		\pan,Prand([-0.3,0,0.3],inf),
		\amprel,Pwhite (0.08,1,inf),
	)
)
)

Pdef(\crt).stop;///////////FM
Pdef(\crt).play;
2

Shoot me , I just deleted them and it works
I blame today’s heat frying my brain :



//////Select Synthdefs

(
SynthDef(\twoop,
{
|fmamt=2,modoffset=24,moatt=0.001,modrel=0.500,ampatt=0.001,amprel=0.800,pitch=48,outt=0.3,pan=0.2,feed=0.2|
var mod,modenv,ampenv,carr;

		mod=SinOscFB.ar((pitch+modoffset).midicps,feedback:feed)*fmamt;
		modenv=EnvGen.ar(Env.perc(moatt,modrel),doneAction:0);
		ampenv=EnvGen.ar(Env.perc(ampatt,amprel),doneAction:2);
		carr=SinOsc.ar(pitch.midicps,(mod*modenv))*ampenv*outt;
		carr=Pan2.ar(carr,pos:pan);
		Out.ar(0,carr);
}).add
);


///////////////////////

(
SynthDef (\simple,
{
|att=0.001,dec=0.200,mod=500,pitch=0,filterfreq=400,reso=0.5,vol=0.5,pan=0|
var sig,env;

		env=EnvGen.ar(Env([0,1,0],[att,dec],[0,-5]),doneAction:2);
		sig=Pulse.ar(pitch.midicps,mul:0.5)+Saw.ar((pitch+0.2).midicps,mul:0.5);///////I an
		sig=RLPF.ar(sig,filterfreq+(env*mod).clip(40,20000),rq:reso);
		sig=sig*env;
		sig=Pan2.ar(sig,pos:pan);
		Out.ar(0,sig*vol)
}).add
)
///////////
(
SynthDef (\kick,
{
		arg pitch=50,patt=0.001,pdec=0.325,pcurve=(-50),pamt=100,att=0.001,dec=0.700,noisefreq=100,shamt=4,vol=0.3;
		var kick,penv,ampenv,noiseosc;
		penv=EnvGen.ar(Env([0,1,0],[patt,pdec],[0,pcurve]),doneAction:2);
		kick=SinOsc.ar(pitch+(penv*pamt))*0.9;
		noiseosc=LPF.ar(WhiteNoise.ar(0.1),noisefreq);
		kick=(noiseosc+kick)*EnvGen.ar(Env([0,1,0],[att,dec],[0,-5]))!2;
		kick=SineShaper.ar(kick*shamt)*vol;
		kick=HPF.ar(kick,50);
		Out.ar(0,kick);
}).add;
)

///////Select pdefs

(
Pdef(
	\crt,
	Pbind(
		\instrument,
		\twoop,
		\pitch,Pseq([Pseq([48,72,48,\,60,48,48,48]-10,4),Pseq([48,72,48,\,60,48,48,48]-17,2),Pseq([48,72,48,\,60,48,48,48]-15,2)],inf),
		\dur,Pseq([1/4,1/8,1/4,1/4,1/8,1/4,1/8,1/4],inf),
		\fmamt,Prand([2,1,3,4],inf),
		\modrel,Prand([0.425,0.525,0.500,0.550,1,0.625,0.500,0.5,2.8],inf),
		\modoffset,Prand([12,0,12,24],inf),
		\feed,Pwhite(0.3,0.5,inf),
		\pan,Prand([-0.3,0,0.3],inf),
		\amprel,Pwhite (0.08,1,inf),
	)
)
)
///////////////
(
Pdef(\zxcv,

	Pbind(\instrument,\simple,
	\dur,Pseq([0.5,1,0.5,0.250]/0.5,inf),
		\pitch,Pseq([[60,65,67],[62,69],[65,58],Pseq([72,69,76],3)],inf)-12,
	\filterfreq,Prand([400,440,600,400,2000,400,900,350,3000],inf),
	\dec,Pseq([0.125,0.125,4.125,0.7,0.25],inf),
	\att,Pseq([0.001,0.1,0.001,0.1,0.001,0.2],inf),
	\reso,Pseq([0.5,0.5,0.5,0.2,0.5,0.5,0.5],inf),
	\vol,Pseq([0.1,0.2],inf),
	\pan,Pseq([-0.3,1,0,0.3,1],inf),
	)
))
///////////
(
Pdef(\kik,
	Pbind(\instrument,\kick,
		\dur,Pseq([1/2],inf),
		\pitch,Pseq([50,50],inf),
		\pdec,0.6,
		\shamt,Pseq([2,2,2,2],inf),
		\vol,0.8,
))
)



Pdef(\zxcv).play;
Pdef(\zxcv).stop;



Pdef(\kik).play;
Pdef(\kik).stop;

Pdef(\crt).stop;///////////FM
Pdef(\crt).play;