Weights in Pwrand as patterns?

LFSaw · February 19, 2020, 12:50pm

I try to implement weighted sums in the Patterns system and thought this should work (ignore the boringness of the code, it is simplified) but it apparently throws an error for me, anyone knows why?

a = Pwrand([false, true], [Pseq([1, 0], inf), Pseq([0, 1], inf)], inf).asStream;
a.next;

error:

// [...]
^^ The preceding error dump is for ERROR: Primitive '_ArrayWIndex' failed.
Wrong type.
RECEIVER: [ a Pseq, a Pseq ]

anyone has an idea what I am doing wrong?

scztt · February 19, 2020, 1:05pm

Hey till
I’ve got an improved Pw that can take patterns for weights, and doesn’t require normalized weight values, I’ll post when I’m at my computer.
(To answer your q: I recall this being a limitation of Pwrand, which lead me to make the newer version)

jamshark70 · February 19, 2020, 3:24pm

Simpler answer: for an array of patterns, you need Ptuple.

Ptuple([Pseq([1, 0], inf), Pseq([0, 1], inf)]).collect(_.normalizeSum)

hjh

scztt · February 19, 2020, 11:10pm

gist.github.com

https://gist.github.com/scztt/a713d273495ab6db48d6b07a73c1f222

Pwnrand.sc

Pwnrand : ListPattern {
	var <>weights;

	*new { arg list, weights, repeats=1;
		^super.new(list, repeats).weights_(weights)
	}

	embedInStream {  arg inval;
		var item, weightsVal, repeatStream;
		var weightsStream = Ptuple(weights).asStream;

This file has been truncated. show original

Pwnrand_example.scd

Pwnrand([1, 2, 3], [10, 1, 1], 100).asStream.all.histo.plot; // weights are normalized for each .next()
Pwnrand([1, 2, 3], [2, 1, 1], 100).asStream.all.histo.plot; 
Pwnrand([1, 2], [2, 1, 1, 10], 100).asStream.all.histo.plot; // extra weights are removed before normalizing
Pwnrand([1, 2, 3, 4], [2, 1], 100).asStream.all.histo.plot; // unspecified weights are assumed to be 0
Pwnrand([1, 2], [1, Pseq([0.0, 1]).stutter(50)], 100).asStream.all.histo.plot; // Weights can be streams

I’ve found I use this class VERY heavily - composing by using Pwnrands containing Pseg's for each weight has become a pretty core compositional pattern for me.

jamshark70 · February 20, 2020, 2:11am

That is very nice! Would be worth quarking.

hjh

LFSaw · February 20, 2020, 8:19am

Thanks, @scztt, this is cool!

I also tried @jamshark70 's solution:

Pwrand([1, 2, 3], Ptuple([10, 1, 1]).collect(_.normalizeSum), 100).asStream.all.histo.plot; // weights are normalized for each .next()
Pwrand([1, 2, 3], Ptuple([2, 1, 1]).collect(_.normalizeSum), 100).asStream.all.histo.plot; 
Pwrand([1, 2], Ptuple([1, Pseq([0.0, 1]).stutter(50)]).collect(_.normalizeSum), 100).asStream.all.histo.plot; // Weights can be streams

Which allows the same behaviour (regarding normalisation and integration of patterns into the weights). So, there we have two solutions… but I am required by the mechanism of this forum to pick one and James’ works without extensions…

I learned a lot from this, thanks!